Tom写的转化函数......

SQL> create or replace function to_base( p_dec in number, p_base in number )
2 return varchar2
3 is
4 l_str varchar2(255) default NULL;
5 l_num number default p_dec;
6 l_hex varchar2(16) default '0123456789ABCDEF';
7 begin
8 if ( p_dec is null or p_base is null )
9 then
10 return null;
11 end if;
12 if ( trunc(p_dec) <> p_dec OR p_dec < 0 ) then
13 raise PROGRAM_ERROR;
14 end if;
15 loop
16 l_str := substr( l_hex, mod(l_num,p_base)+1, 1 ) || l_str;
17 l_num := trunc( l_num/p_base );
18 exit when ( l_num = 0 );
19 end loop;
20 return l_str;
21 end to_base;
22 /

Function created.

SQL>
SQL>
SQL> create or replace function to_dec
2 ( p_str in varchar2,
3 p_from_base in number default 16 ) return number
4 is
5 l_num number default 0;
6 l_hex varchar2(16) default '0123456789ABCDEF';
7 begin
8 if ( p_str is null or p_from_base is null )
9 then
10 return null;
11 end if;
12 for i in 1 .. length(p_str) loop
13 l_num := l_num * p_from_base + instr(l_hex,upper(substr(p_str,i,1)))-1;
14 end loop;
15 return l_num;
16 end to_dec;
17 /

Function created.

SQL> show errors
No errors.
SQL>
SQL> create or replace function to_hex( p_dec in number ) return varchar2
2 is
3 begin
4 return to_base( p_dec, 16 );
5 end to_hex;
6 /

Function created.

SQL> create or replace function to_bin( p_dec in number ) return varchar2
2 is
3 begin
4 return to_base( p_dec, 2 );
5 end to_bin;
6 /

Function created.

SQL> create or replace function to_oct( p_dec in number ) return varchar2
2 is
3 begin
4 return to_base( p_dec, 8 );
5 end to_oct;
6 /

Function created.
SQL> select to_bin(50) bin, to_oct(50) oct , to_hex(50) hex from dual;

BIN OCT HEX
---------- ---------- ----------
110010 62 32

SQL> select to_dec('110010',2) ,to_dec('62',8) ,to_dec('32',16) from dual;

TO_DEC('110010',2) TO_DEC('62',8) TO_DEC('32',16)
------------------ -------------- ---------------
50 50 50