ITPub博客

首页 > Linux操作系统 > Linux操作系统 > [20190909]完善vim的bccacl插件.txt

[20190909]完善vim的bccacl插件.txt

原创 Linux操作系统 作者:lfree 时间:2019-09-09 23:03:32 0 删除 编辑

[20190909]完善vim的bccacl插件.txt

http://blog.itpub.net/267265/viewspace-2140886/
http://blog.itpub.net/267265/viewspace-2140823/
http://blog.itpub.net/267265/viewspace-2140602/

http://blog.itpub.net/267265/viewspace-2142560/=>[20170725]vim调用bccalc插件问题.txt

--//我个人很喜欢在vim调用bc做各种计算,使用插件bccale,参考前面的链接.一位网友建议我做一些完善,要求能智能判断输入变量
--//是10进制还是16进制,实际上一些情况无法判断.

--//实际上当时发现存在一些小bug,我很少使用它做计算,特别是小数点的运算。
1/30000*325=.0183333333333333225
--//注不需要输入等号,打入\bc.显示结果.

--//而我在bc -l下执行如下:
1/30000*325
.01083333333333333225

--//上个星期6,7再次检查,发现这个bug实际上很简单,原作者做了删除尾部0的操作。
" strip trailing 0s in decimals
" let answer = substitute (answer, '\.\(\d*[1-9]\)0\+', '.\1', "")
--//应该修改如下,正则表达式要加入$,这样才是匹配尾部0的操作。
" strip trailing 0s in decimals
let answer = substitute (answer, '\.\(\d*[1-9]\)0\+$', '.\1', "")

--//另外我当时windows与linux版本分开,今天把它们合并起来。windows下处理^存在问题。修改如下:
" escape chars for shell
if has("unix")
    let str = escape (str, '*();&><|^')
else
    let str = escape (str, '*();&><|')
endif

--//解决插入模式下计算问题,我修改的版本给CalcLines加入参数。
"" calculate from insertmode
inoremap =: = <Esc>"eyy:call CalcLines()<CR>a
--//修改如下:
"" calculate from insertmode
inoremap =: = <Esc>"eyy:call CalcLines(0)<CR>a

--//增加16进制的识别,很简单的检查,如果无法识别当10进制,如果明确16进制最好在前面输入0x.
--//加入dba块地址,scn的转换10,16进制的功能,并加入注解便于阅读。

$ cat bccalc.vim
"" calculate expression entered on command line and give answer, e.g.:
" :Calculate sin (3) + sin (4) ^ 2
command! -nargs=+ Calculate echo "<args> = " . Calculate ("<args>",0)

"" calculate expression from selection, pick a mapping, or use the Leader form
"vnoremap ;bc "ey`>:call CalcLines()<CR>
"vnoremap <Leader>bc "ey`>:call<SID>CalcBC(1)<CR>

vnoremap ;bc "ey`>:call CalcLines(0)<CR>
vnoremap ;10 "ey`>:call CalcLines(10)<CR>
vnoremap ;16 "ey`>:call CalcLines(16)<CR>

vnoremap ;22 "ey`>:call CalcLines(22)<CR>
vnoremap ;dba "ey`>:call CalcLines(22)<CR>

vnoremap ;32 "ey`>:call CalcLines(32)<CR>
vnoremap ;scn "ey`>:call CalcLines(32)<CR>

vnoremap ;ss "ey`>:call CalcLines(10016)<CR>
vnoremap ;rr "ey`>:call CalcLines(20016)<CR>
vnoremap ;hd "ey`>:call CalcLines(30016)<CR>

"" calculate expression on current line, pick a mapping, or use the Leader
nnoremap  <Leader>bx <Esc>A <Esc>"eyy$:call CalcLines(0)<CR>
nnoremap  <Leader>bc <Esc>A = <Esc>"eyy:call CalcLines(0)<CR>

" convert hexdecimal to decimal
nnoremap  <Leader>10 <Esc>A = <Esc>"eyy:call CalcLines(10)<CR>

" convert decimal to hexdecimal
nnoremap  <Leader>16 <Esc>A = <Esc>"eyy:call CalcLines(16)<CR>

" split dba(10) to file# and block#
nnoremap  <Leader>22  <Esc>A = <Esc>"eyy:call CalcLines(22)<CR>
nnoremap  <Leader>dba <Esc>A = <Esc>"eyy:call CalcLines(22)<CR>

" split scn(10) into scn_wrap,scn_base
nnoremap  <Leader>32  <Esc>A = <Esc>"eyy:call CalcLines(32)<CR>
nnoremap  <Leader>scn <Esc>A = <Esc>"eyy:call CalcLines(32)<CR>

" convert scn_wrap,scn_base(10) or scn_wrap,scn_base(16 to 10 or 16 base
nnoremap  <Leader>ss <Esc>A = <Esc>"eyy:call CalcLines(10016)<CR>

" convert file#,block#(10) or file#,block#(16) to 10 or 16 base
nnoremap  <Leader>rr <Esc>A = <Esc>"eyy:call CalcLines(20016)<CR>

" convert hexdecimal to decimal or decimal to hexdecimal
nnoremap  <Leader>hd <Esc>A = <Esc>"eyy:call CalcLines(30016)<CR>

"nnoremap  <Leader>bc "eyy$:call<SID>CalcBC(0)<CR>
"" calculate from insertmode
inoremap =: = <Esc>"eyy:call CalcLines(0)<CR>a

" ---------------------------------------------------------------------
"  Calculate:
"    clean up an expression, pass it to bc, return answer
function! Calculate (s,flag)
    
    let has_hex = 0
    let str = a:s

    " remove newlines and trailing spaces
    let str = substitute (str, "\n",   "", "g")
    let str = substitute (str, '\s*$', "", "g")

    " sub common func names for bc equivalent
    let str = substitute (str, '\csin\s*(',  's (', 'g')
    let str = substitute (str, '\ccos\s*(',  'c (', 'g')
    let str = substitute (str, '\catan\s*(', 'a (', 'g')
    let str = substitute (str, "\cln\s*(",   'l (', 'g')
    let str = substitute (str, '\clog\s*(',  'l (', 'g')
    let str = substitute (str, '\cexp\s*(',  'e (', 'g')

    " alternate exponitiation symbols
    let str = substitute (str, '\*\*', '^', "g")
    let str = substitute (str, '`', '^',    "g")
    let str = substitute (str, '\^', '^^^^',    "g")

    " escape chars for shell
    if has("unix")
        let str = escape (str, '*();&><|^')
    else
        let str = escape (str, '*();&><|')
    endif

    let preload = exists ("g:bccalc_preload") ? g:bccalc_preload : ""

    " run bc
    " return str
    " let answer = system ("echo " . str . " \| bc -l " . preload)

    if a:flag == 0
         let answer = system ("echo " . str . " \| bc -l " . preload)
         " let answer = answer . "   ". str
    endif

    if a:flag == 10
        let str = substitute (str, "0x", "", "g")
        let str = toupper ( str )
        let answer = system ("echo ibase=16 ;" . str .  " \| bc -l " . preload)
    endif

    if a:flag == 16
        let answer = system ("echo obase=16 ;" . str .  " \| bc -l " . preload)
        let answer = "0x" . tolower ( answer )
    endif

    let has_hex = Check_hex( str )

    if a:flag == 22
        if has_hex == 1
            let str = toupper ( str )
            let str = substitute (str, "0x", "", "g")
            " 0x400000 hexdecimal = 4194304 (10) = 2^22(10)
            let answer  = system ("echo ibase=16 ;" . str . "/400000" . " \| bc " . preload)
            let answer1 = system ("echo ibase=16 ;" . str . "%400000" . " \| bc " . preload)
        else
            let answer  = system ("echo " . str . "/4194304" . " \| bc " . preload)
            let answer1 = system ("echo " . str . "%4194304" . " \| bc " . preload)
        endif
        " let answer = "set dba " . answer . "," . answer1
        let answer = "set dba " . answer . "," . answer1 ." = alter system dump file " . answer . " block " . answer1
    endif

    if a:flag == 32
        if has_hex == 1
            let str = toupper ( str )
            let str = substitute (str, "0x", "", "g")
            " 0x100000000 hexdecimal = 4294967296(10) = 2^32(10)
            let answer  = system ("echo ibase=16 ;" . str . "/100000000" . " \| bc " . preload)
            let answer1 = system ("echo ibase=16 ;" . str . "%100000000" . " \| bc " . preload)
            let answer2 = system ("echo obase=16 ;ibase=16 ;" . str . "/100000000" . " \| bc " . preload)
            let answer3 = system ("echo obase=16 ;ibase=16 ;" . str . "%100000000" . " \| bc " . preload)
        else
            let answer  = system ("echo " . str . "/4294967296" . " \| bc " . preload)
            let answer1 = system ("echo " . str . "%4294967296" . " \| bc " . preload)
            let answer2 = system ("echo obase=16 ;" . str . "/4294967296" . " \| bc " . preload)
            let answer3 = system ("echo obase=16 ;" . str . "%4294967296" . " \| bc " . preload)
        endif
        " let answer = "scn_wrap,scn_base: " . answer . " " . answer1
        let answer = "scn_wrap,scn_base(10): " . answer . "," . answer1 . " =scn_wrap,scn_base(16): " . "0x" . tolower (answer2) . "," . "0x" . tolower(answer3)
    endif


    if a:flag == 10016
        if has_hex == 1
            let str = toupper ( str )
            let str = substitute (str, "0x", "", "g")
            " 0x100000000 hexdecimal = 4294967296(10) = 2^32(10)
            let str = substitute (str, "[,.]", "*100000000+", "g")
            let answer  = system ("echo obase=10 ;ibase=16 ;" . str .  " \| bc -l " . preload)
            let answer1 = system ("echo obase=16 ;ibase=16 ;" . str .  " \| bc -l " . preload)
            let answer = "scn_wrap,scn_base(10): " . answer . " = scn_wrap,scn_base(16): " . "0x" . tolower (answer1)
        else
            let str = substitute (str, "[,.]", "*4294967296+", "g")
            let answer  = system ("echo " . str . " \| bc -l " . preload)
            let answer1 = system ("echo obase=16 ;" . str .  " \| bc -l " . preload)
            let answer = "scn_wrap,scn_base(10): " . answer . " = scn_wrap,scn_base(16): " . "0x" . tolower (answer1)
        endif
    endif

    if a:flag == 20016
        if has_hex == 1
            let str = toupper ( str )
            let str = substitute (str, "0x", "", "g")
            " 0x400000 hexdecimal = 4194304 (10) = 2^22(10)
            let str = substitute (str, "[,.]", "*400000+", "g")
            let answer  = system ("echo obase=10 ;ibase=16 ;" . str .  " \| bc -l " . preload)
            let answer1 = system ("echo obase=16 ;ibase=16 ;" . str .  " \| bc -l " . preload)
            let answer = "file#,block#(10): " . answer . " = file#,block#(10): " . "0x" . tolower (answer1)     
        else
            let str = substitute (str, "[,.]", "*4194304+", "g")
            let answer  = system ("echo " . str . " \| bc -l " . preload)
            let answer1 = system ("echo obase=16 ;" . str .  " \| bc -l " . preload)
            let answer = "file#,block#(10): " . answer . " = file#,block#(16): " . "0x" . tolower (answer1)
        endif
    endif

    if a:flag == 30016
        if has_hex == 1
            let str = substitute (str, "0x", "", "g")
            let str = toupper ( str )
            let answer = system ("echo ibase=16 ;" . str .  " \| bc -l " . preload)
        else
            let answer = system ("echo obase=16 ;" . str .  " \| bc -l " . preload)
            let answer = "0x" . tolower ( answer )
        endif
    endif

    " strip newline
    let answer = substitute (answer, "\n", "", "g")

    " strip trailing 0s in decimals
    " let answer = substitute (answer, '\.\(\d*[1-9]\)0\+', '.\1', "")
    let answer = substitute (answer, '\.\(\d*[1-9]\)0\+$', '.\1', "")

    return answer
endfunction

" ---------------------------------------------------------------------
" CalcLines:
"
" take expression from lines, either visually selected or the current line,
" pass to calculate function, echo or past answer after '='
function! CalcLines(flag)

    let has_equal = 0

    " remove newlines and trailing spaces
    let @e = substitute (@e, "\n", "",   "g")
    let @e = substitute (@e, '\s*$', "", "g")

    " if we end with an equal, strip, and remember for output
    if @e =~ "=$"
        let @e = substitute (@e, '=$', "", "")
        let has_equal = 1
    endif

    " if there is another equal in the line, assume chained equations, remove
    " leading ones
    let @e = substitute (@e, '^.\+=', '', '')

    let answer = Calculate (@e,a:flag)

    " append answer or echo
    if has_equal == 1
        exec "normal a" . answer
    else
        echo "answer = " . answer
    endif
endfunction

" ---------------------------------------------------------------------
" Check_hex:
"
" Check if the string contains 0x, a, b, c, d, e, f  return has_hex=1
function! Check_hex(str)
    let has_hex = 0
    let ss = a:str
    let ss = tolower ( ss )

    if ss =~ "0x"
        let has_hex = 1
        return has_hex
    endif

    if ss =~ "a"
        let has_hex = 1
        return has_hex
    endif

    if ss =~ "b"
        let has_hex = 1
        return has_hex
    endif

    if ss =~ "c"
        let has_hex = 1
    endif

    if ss =~ "d"
        let has_hex = 1
        return has_hex
    endif

    if ss =~ "e"
        let has_hex = 1
        return has_hex
    endif

    if ss =~ "f"
        let has_hex = 1
        return has_hex
    endif

endfunction

--//拷贝到plugin目录就ok了。简单介绍一些使用:
1.输入算式,按<esc> \bc,也可以在插入模式下输入=:(当然要快,慢了就无效了)。
  如果算式最后是有=,可以按<esc> \bx
2.\10 对应的是16进制转10进制
  \16 对应的是10进制转16进制
  \hd 猜测双向转化(简单记忆: h表示16,d表示d),10->16 or 16->10.可能不对,如果16进制没有abcdef 0x等字符,当作10->16计算.
3.\rr 对应是file#,block#转化为10,16进制数, 注意参数也是猜测.
4.\ss 对应是scn_wrap,scn_base转化为10,16进制数,注意参数也是猜测.
5.在visual模式下,对应的命令仅仅\换成;,可以在提示行显示结果。
  仅仅注意1个问题使用shift+方向键,进入的select模式(windows用户喜欢这样操作),必须按ctrl+g切换为visual模式。
  再输入相应命令.

--//一些例子:
4229121 = 0x408801                                                  (输入\16)
0x408801 = 4229121                                                  (输入\10)
408801 = 4229121                                                    (输入\10)
0x408801 = 4229121                                                  (输入\hd)
408801 = 0x63ce1                                                    (输入\hd,注:因为无法判别输入10还是16进制,输入变量当)
                                                                    (作10进制,可以在前面加入0x表示16进制)
4229121 = set dba 1,34817 = alter system dump file 1 block 34817    (输入\22 或者 \dba)
1,34817 = file#,block#(10): 4229121 = file#,block#(16): 0x408801    (输入\rr)
34817 = 0x8801                                                      (输入\16)
0x1.0x8801 = file#,block#(10): 4229121 = file#,block#(10): 0x408801 (输入\rr)

1.8801 = file#,block#(10): 4203105 = file#,block#(16): 0x402261     (输入\rr,无法判别输入参数是10还是16进制,当10进制处理)
4203105 = set dba 1,8801 = alter system dump file 1 block 8801      (输入\22 或者 \dba)
0x1.8801 = file#,block#(10): 4229121 = file#,block#(10): 0x408801   (输入\rr)

12884914013 = scn_wrap,scn_base(10): 3,12125 =scn_wrap,scn_base(16): 0x3,0x2f5d      (输入\32 或者 \scn)
3,12125 = scn_wrap,scn_base(10): 12884914013 = scn_wrap,scn_base(16): 0x300002f5d    (输入\ss)
0x3,0x2f5d = scn_wrap,scn_base(10): 12884914013 = scn_wrap,scn_base(16): 0x300002f5d (输入\ss)
3.2f5d = scn_wrap,scn_base(10): 12884914013 = scn_wrap,scn_base(16): 0x300002f5d     (输入\ss)

1+34+3 = 38                                                         (输入\bc)
1+34+3 = 38                                                         (输入\bx,在算式最后有等号的情况下)
1+34+3                                                              (输入\bx,在算式没有等号的情况下,在提示行显示结果)
1+34+3 = 38                                                         (在插入模式下输入等号后快速输入:,可以直接输出结果。)
--//希望大家给一些建议,我如果有时间继续完善这个插件。
--//下载地址:https://files.cnblogs.com/files/lfree/bccalc_win.rar

来自 “ ITPUB博客 ” ,链接:http://blog.itpub.net/267265/viewspace-2656546/,如需转载,请注明出处,否则将追究法律责任。

请登录后发表评论 登录
全部评论
熟悉oracle相关技术,擅长sql优化,rman备份与恢复,熟悉linux shell编程。

注册时间:2008-01-03

  • 博文量
    2471
  • 访问量
    6278345