ITPub博客

首页 > Linux操作系统 > Linux操作系统 > 怎样将数字金额转为大写汉字金额(存档)

怎样将数字金额转为大写汉字金额(存档)

原创 Linux操作系统 作者:blueshine07 时间:2011-09-07 16:06:42 0 删除 编辑
怎样将数字金额转为大写汉字金额。下面的函数是转自pub的一位兄台写的,存档。
--此函数处理数字小写金额转换为大写金额             
  --    函数名:CONVERT_MONEY                                           
  --   参 数:v_number  类型:number     
  FUNCTION CONVERT_MONEY(JE NUMBER) RETURN VARCHAR2 IS
    RESULT VARCHAR2(100);
    I      PLS_INTEGER;
    SNUM   VARCHAR2(20) := LTRIM(REPLACE(TO_CHAR(ABS(JE),
                                                 '9999999999999990.99'),
                                         '.'));
    LEN    PLS_INTEGER := LENGTH(SNUM);
    SCH    VARCHAR2(20) := '零壹贰叁肆伍陆柒捌玖';
    SJIN   VARCHAR2(50) := '分角圆拾佰仟万拾佰仟亿拾佰仟万拾佰仟';
    SRMB   VARCHAR2(100) := '';
    NUM    PLS_INTEGER;
    JIN    VARCHAR(2);
    S_NUM  PLS_INTEGER := 0; --'0'起始位置
    E_NUM  PLS_INTEGER := 0; --'0'结束位置
  BEGIN
    FOR I IN 1 .. LEN LOOP
      NUM := TO_NUMBER(SUBSTR(SNUM, I, 1));
      IF NUM <> 0 THEN
        --非'0'时处理:
        IF S_NUM = 0 THEN
          SRMB := SRMB || SUBSTR(SCH, NUM + 1, 1) ||
                  SUBSTR(SJIN, LEN - I + 1, 1); --前面字符非'0', 正常联接...
        ELSE
          SRMB := SRMB || --否则:
                  CASE
                    WHEN S_NUM = E_NUM THEN --前面只有一个'0'
                     CASE S_NUM
                       WHEN 7 THEN
                        '万' --只处理进位
                       WHEN 11 THEN
                        '亿'
                       WHEN 15 THEN
                        '万'
                     END
                    WHEN E_NUM < 12 THEN --否则(多个'0'处理)
                     CASE
                       WHEN S_NUM < 7 THEN
                        '' --万以内..
                       WHEN S_NUM < 11 THEN
                        CASE
                          WHEN E_NUM < 8 AND S_NUM < 10 THEN
                           '万'
                        END
                       WHEN S_NUM < 15 THEN
                        CASE
                          WHEN E_NUM < 12 THEN
                           '亿'
                        END
                       ELSE
                        '万亿'
                     END
                    WHEN E_NUM < 16 AND S_NUM > 14 THEN
                     '万'
                  END || CASE
                    WHEN S_NUM > 3 AND E_NUM < 3 THEN
                     '圆零'
                    WHEN E_NUM = 3 THEN
                     '圆'
                    WHEN E_NUM NOT IN (7, 11, 15) OR S_NUM - E_NUM > 2 THEN
                     '零'
                  END;
          SRMB := SRMB || SUBSTR(SCH, NUM + 1, 1) ||
                  SUBSTR(SJIN, LEN - I + 1, 1);
        END IF;
        S_NUM := 0;
        E_NUM := 0;
      ELSE
        IF S_NUM = 0 THEN
          --当s_num = 0时'0'串起始,
          S_NUM := LEN - I + 1; --记录开始
          E_NUM := S_NUM; --各结整位置。
        ELSE
          E_NUM := LEN - I + 1; --否则新的结整位置。
        END IF;
      END IF;
    END LOOP;
    IF S_NUM <> 0 THEN
      --此时以'0'结尾
      SRMB := SRMB || CASE
                WHEN S_NUM = LEN THEN
                 '零圆整' --全'0'串,加...
                WHEN S_NUM = 1 OR S_NUM = 2 THEN
                 '整' --分(1),角(2)后加...
                WHEN S_NUM < 7 OR S_NUM = 10 THEN
                 '圆整'
                WHEN S_NUM < 11 THEN
                 '万圆整'
                WHEN S_NUM < 15 THEN
                 '亿圆整'
                ELSE
                 '万亿圆整'
              END;
    ELSE
      SRMB := SRMB || '整'; --不以'0'结尾,加...
    END IF;
    IF JE < 0 THEN
      SRMB := '负' || SRMB;
    END IF;
    RETURN SRMB;
  END CONVERT_MONEY;

来自 “ ITPUB博客 ” ,链接:http://blog.itpub.net/25103190/viewspace-706833/,如需转载,请注明出处,否则将追究法律责任。

上一篇: 税的取数SQL
请登录后发表评论 登录
全部评论

注册时间:2011-08-26

  • 博文量
    55
  • 访问量
    151252