ITPub博客

首页 > 数据库 > Oracle > oracle数据库自动发邮件实现报警功能

oracle数据库自动发邮件实现报警功能

原创 Oracle 作者:甲骨文技术支持 时间:2018-11-14 17:06:42 0 删除 编辑

我们之前有个需求,需要每天检查oracle里的job是否执行成功,人工查比较麻烦,写了一个存储过程,定时发邮件。


一共涉及两个存储过程,第一个是设置发邮件给谁和发的内容。


CREATE OR REPLACE PROCEDURE CHECK_JOBS_GL
AS
  /******
   检查定时任务(jobs)是否执行成功,并发邮件。by guoliang 2016年6月28日
  ******/
 V_NUMBER VARCHAR2(10);
 
BEGIN
  -- 检查dba_jobs表查看是否有执行错误的job
 
    SELECT  COUNT(1) INTO V_NUMBER  FROM USER_JOBS WHERE SCHEMA_USER = 'Mxxxxx' AND failures <> '0';
    IF V_NUMBER = '0' THEN 
     send_mail_gl('guoliang@xxxx.cn','数据库定时任务执行成功','您好,数据库定时任务执行成功,请知悉');
     
    ELSE
     send_mail_gl('guoliang@xxxx.cn','请注意,数据库定时任务执行失败','您好,数据库定时任务执行失败,请排查');
     
    END IF;
DBMS_OUTPUT.put_line(V_NUMBER);
      
END;


第二个就是上面提到的send_mail_gl程序:


CREATE OR REPLACE PROCEDURE SEND_MAIL_GL(p_recipient VARCHAR2, -- 邮件接收人
                                         p_subject VARCHAR2, -- 邮件标题
                                         p_message VARCHAR2 -- 邮件正文
)
IS
  --下面四个变量请根据实际邮件服务器进行赋值
  v_mailhost VARCHAR2(30) := 'smtp.exmail.qq.com'; --SMTP服务器地址
  v_user VARCHAR2(30) := 'devops@xxx.cn'; --登录SMTP服务器的用户名
  v_pass VARCHAR2(20) := 'xxxx'; --登录SMTP服务器的密码
  v_sender VARCHAR2(50) := 'devops@xxx.cn'; --发送者邮箱,一般与 ps_user 对应
  v_conn UTL_SMTP.connection; --到邮件服务器的连接
  v_msg VARCHAR2(4000); --邮件内容
BEGIN
  v_conn := UTL_SMTP.open_connection(v_mailhost, 25);
  UTL_SMTP.ehlo(v_conn, v_mailhost); --是用 ehlo() 而不是 helo() 函数
  --否则会报:ORA-29279: SMTP 永久性错误
  UTL_SMTP.command(v_conn, 'AUTH LOGIN'); -- smtp服务器登录校验
  UTL_SMTP.command(v_conn,
                   UTL_RAW.cast_to_varchar2(UTL_ENCODE.base64_encode(UTL_RAW.cast_to_raw(v_user))));
  UTL_SMTP.command(v_conn,
                   UTL_RAW.cast_to_varchar2(UTL_ENCODE.base64_encode(UTL_RAW.cast_to_raw(v_pass))));
  UTL_SMTP.mail(v_conn, '<' || v_sender || '>'); --设置发件人
  UTL_SMTP.rcpt(v_conn, '<' || p_recipient || '>'); --设置收件人
  -- 创建要发送的邮件内容 注意报头信息和邮件正文之间要空一行
  v_msg := 'Date:' || TO_CHAR(SYSDATE, 'yyyy mm dd hh24:mi:ss') ||
           UTL_TCP.CRLF || 'From: ' || v_sender || '' || UTL_TCP.CRLF ||
           'To: ' || p_recipient || '' || UTL_TCP.CRLF || 'Subject: ' ||
           p_subject || UTL_TCP.CRLF || UTL_TCP.CRLF -- 这前面是报头信息
           || p_message; -- 这个是邮件正文
  UTL_SMTP.open_data(v_conn); --打开流
  UTL_SMTP.write_raw_data(v_conn, UTL_RAW.cast_to_raw(v_msg)); --这样写标题和内容都能用中文
  UTL_SMTP.close_data(v_conn); --关闭流
  UTL_SMTP.quit(v_conn); --关闭连接
EXCEPTION
  WHEN OTHERS THEN
    DBMS_OUTPUT.put_line(DBMS_UTILITY.format_error_stack);
    DBMS_OUTPUT.put_line(DBMS_UTILITY.format_call_stack);
END SEND_MAIL_GL;


来自 “ ITPUB博客 ” ,链接:http://blog.itpub.net/20893244/viewspace-2219989/,如需转载,请注明出处,否则将追究法律责任。

上一篇: python变量
请登录后发表评论 登录
全部评论
2009年获得Oracle OCM认证,ITPUB社区OCM联盟成员,熟悉Oracle,mysql,Python,Zabbix等。

注册时间:2016-12-31

  • 博文量
    143
  • 访问量
    424623