ITPub博客

首页 > 数据库 > Oracle > PLSQL Language Referenc-PL/SQL静态SQL-静态SQL的描述-光标-显式光标查询中的变量

PLSQL Language Referenc-PL/SQL静态SQL-静态SQL的描述-光标-显式光标查询中的变量

原创 Oracle 作者:LuiseDalian 时间:2014-03-16 17:08:26 0 删除 编辑

显式光标查询中的变量

显示光标的查询可以引用它作用域内的任何变量。当打开光标时,PL/SQL计算查询中的变量,且在识别结果集时使用这些值。后面改变这些变量的值,不会改变结果集。

DECLARE

    sal             employees.salary%TYPE;

    sal_multiple    employees.salary%TYPE;

    factor          INTEGER := 2;

 

    CURSOR c1 IS

        SELECT salary, salary * factor FROM employees

        WHERE job_id LIKE 'AD_%';

 

BEGIN

    OPEN c1;  -- PL/SQL计算factor

 

    LOOP

        FETCH c1 INTO sal, sal_multiple;

        EXIT WHEN c1%NOTFOUND;

        DBMS_OUTPUT.PUT_LINE('factor = ' || factor ||

                             ', sal = ' || sal ||

                             ', sal_multiple = ' || sal_multiple);     

        factor := factor + 1;  -- 不会影响结果集

  END LOOP;

 

  CLOSE c1;

END;

 

--为了改变结果集,必须关闭光标,改变变量的值,然后再次打开光标

DECLARE

    sal           employees.salary%TYPE;

    sal_multiple  employees.salary%TYPE;

    factor        INTEGER := 2;

 

    CURSOR c1 IS

        SELECT salary, salary*factor FROM employees

        WHERE job_id LIKE 'AD_%';

 

BEGIN

    DBMS_OUTPUT.PUT_LINE('factor = ' || factor);

    OPEN c1;  -- PL/SQL 计算factor

    LOOP

        FETCH c1 INTO sal, sal_multiple;

        EXIT WHEN c1%NOTFOUND;

        DBMS_OUTPUT.PUT_LINE('sal = ' || sal ||

                            ', sal_multiple = ' || sal_multiple);      

    END LOOP;

    CLOSE c1;

 

    factor := factor + 1;

    DBMS_OUTPUT.PUT_LINE('factor = ' || factor);

    OPEN c1;  -- PL/SQL 计算factor

    LOOP

        FETCH c1 INTO sal, sal_multiple;

        EXIT WHEN c1%NOTFOUND;

        DBMS_OUTPUT.PUT_LINE('sal = ' || sal ||

                            ', sal_multiple = ' || sal_multiple);

    END LOOP;

    CLOSE c1;

END;

来自 “ ITPUB博客 ” ,链接:http://blog.itpub.net/17013648/viewspace-1122703/,如需转载,请注明出处,否则将追究法律责任。

请登录后发表评论 登录
全部评论

注册时间:2012-02-06

  • 博文量
    1986
  • 访问量
    5678352